begin
	;***Reading data files and variables

        a 		= addfile("File1a.nc","r")
        b 		= addfile("File2a.nc","r")


        a1		= a->rf
        b1 		= b->rf
        lat   		= a->lat
        lon 		= a->lon
	
	;***Calculate the correlation value
        correl		= escorc(b1(lat|:,lon|:,time|:),a1(lat|:,lon|:,time|:))
        correl!0	= "lat"
        correl!1	= "lon"
        correl&lat	= lat
        correl&lon	= lon

        ;***significant values
        sig 		= 0.05
        um 		= rtest(correl(lat|:,lon|:),11,0)
        um!0		= "lat"
        um!1		= "lon"
        um&lat		= lat
        um&lon		= lon

	;***
	wks 		= gsn_open_wks("x11","example")
	;***

	;***Setting the resources for correlation plot
        res 		= True
	res@gsnDraw	= False
	res@gsnFrame	= False
        res@gsnAddCyclic= False
        res@cnFillOn 	= True
        res@cnLinesOn 	= False
	res@mpMinLatF	= 17
	res@mpMaxLatF	= 31
	res@mpMinLonF	= 77
	res@mpMaxLonF  	= 89
	res@mpOutlineOn = False
	res@mpFillOn	= False

        ;plotting correlation plot first
        plot		= gsn_csm_contour_map_ce(wks,correl,res)



	;***Setting the resources for significant value plot
        res2 				= True  	; res2 probability plots
        res2@gsnAddCyclic 		= False
        res2@gsnDraw 			= False 	; Do not draw plot
        res2@gsnFrame 			= False 	; Do not advance frome
        res2@cnLevelSelectionMode 	= "ManualLevels"; set manual contour levels
        res2@cnMinLevelValF 		= 0.00 		; set min contour level
        res2@cnMaxLevelValF 		= 0.10 		; set max contour level
        res2@cnLevelSpacingF		= 0.05 		; set contour spacing
        res2@cnInfoLabelOn 		= False 	; turn off info label
        res2@cnLinesOn 			= False 	; do not draw contour lines
        res2@cnLineLabelsOn 		= False 	; do not draw contour labels
        res2@cnFillScaleF 		= 0.6 		; add extra density

	;plotting significant value plot
	opt 				= True
	opt@gsnShadeFillType 		= "pattern" 	; pattern fill
	opt@gsnShadeLow 		= 2 		; use pattern #2

        plot2 				= gsn_csm_contour(wks,um, res2)
	plot2 				= gsn_contour_shade(plot2,0.05,0.10,opt) 
        overlay (plot, plot2)


        draw (plot)
        frame(wks)


end