wks = gsn_open_wks("png","ncl_maps")

;--- Set some plot options
  res                             = True

  res@gsnMaximize                 = True
  res@mpOutlineOn                 =  True
  res@mpGeophysicalLineThicknessF = 3

  res@pmTickMarkDisplayMode       = "Always"

  res@tmXBLabelFontHeightF        = 0.008
  res@tmXBMajorOutwardLengthF     = 0
  res@tmXBMajorLengthF            = 0
  
  res@tiMainFontHeightF           = 0.013
  res@tiMainFont                  = "helvetica"

  res@tiMainString  = "This is the default in NCL V6.3.0; will stay the same for V6.4.0"
  plot = gsn_csm_map(wks,res)

;---Zoom in on Germany/Swizterland and show four sample plots.
  res@mpMinLatF                   = 45
  res@mpMaxLatF                   = 58
  res@mpMinLonF                   =  4
  res@mpMaxLonF                   = 17
  res@mpNationalLineThicknessF    = 3.0     ; 3x as thick
  res@gsnDraw                     = False
  res@gsnFrame                    = False

  res@tiMainString  = "This is the default in NCL V6.3.0; will stay the same for V6.4.0"
  plot1 = gsn_csm_map(wks,res)

  res@mpOutlineBoundarySets = "National"
  res@tiMainString          = "This is what 'National' boundaries look like in V6.3.0"
  plot2 = gsn_csm_map(wks,res)

  res@mpDataBaseVersion = "MediumRes"    ; Note: in V6.4.0, you will not have to set this
  res@tiMainString      = "This is what 'National' boundaries will look like in V6.4.0"
  plot3 = gsn_csm_map(wks,res)

  res@mpDataSetName     = "Earth..4"
  res@tiMainString      = "By the way, you can still use Earth..4 to further improve outlines"
  plot4 = gsn_csm_map(wks,res)

;---Panel the four zoomed in plots
  pres             = True
  pres@gsnMaximize = True
  gsn_panel(wks,(/plot1,plot2,plot3,plot4/),(/2,2/),pres)