load "./clmDayHour.ncl"

;==================================================
;                    MAIN
;==================================================

   dirCDC = "./"
   filCDC = systemfunc("cd "+dirCDC+"; ls pr_wtr.eatm*nc")

   fCDC   = addfiles(dirCDC+filCDC, "r")
   x      = fCDC[:]->pr_wtr      
   printVarSummary(x)                         ; [time | 7304] x [lat | 73] x [lon | 144]

   HOUR = (/0,6,12,18/)                       ; user specified hours
  
   time    = fCDC[:]->time                    ; time:units = "hours since ?-?-? 00:00:0.0"                               
   TIME    = cd_calendar(time, 0)             ; type float 
   year    = toint( TIME(:,0) )               ; toint strips meta data
   month   = toint( TIME(:,1) )
   day     = toint( TIME(:,2) )               ; day of month 
   hour    = toint( TIME(:,3) )               ; hour of day
                                                                 ; check for calendar attribute
   if (isatt(time,"calendar")) then           ; default is gregorian
       year@calendar = time@calendar         
   end if

   ddd     = day_of_year(year, month, day) 
   if (isatt(time,"calendar")) then           ; default is gregorian
       ddd@calendar = time@calendar  
   end if

   yyyydddhh = year*100000 + ddd*100 + hour                       ; needed for input
   if (isatt(time,"calendar")) then 
       yyyydddhh@calendar = time@calendar  
   end if

   opt_shape  = False
   clmDayHour = clmDayHourTLL (x, yyyydddhh, HOUR, opt_shape)
   printVarSummary(clmDayHour)                ; [dddhh | 1464] x [lat | 73] x [lon | 144]
   printMinMax(clmDayHour,0)
   print("=========================")
   if (opt_shape) then
       print(clmDayHour(:,:,{40},{255}))
       printMinMax(clmDayHour(:,:,{40},{255}),0)
   else
       print(clmDayHour(:,{40},{255}))
       printMinMax(clmDayHour(:,{40},{255}),0)
   end if