;
; Illustrates a bug with cnLowLabelFontHeightF and cnLowLabelAngleF. 
; These resources have no effect, but setting cnHighLabelAngleF
; cnHighLableFontHeightF affects both the high and low labels.
;
begin
  f    = addfile ("$NCARG_ROOT/lib/ncarg/data/cdf/uv300.nc", "r")
  u    = f->U                      ; (time,lat,lon)
  v    = f->V

  div = uv2dvG_Wrap(u,v)           ; u,v ==> divergence
  chi = ilapsG_Wrap ( div , 0)
  chi = (/chi/1e6/)
  chi@long_name = "velocity potential"
  chi@units     = "m/s" 

  wks  = gsn_open_wks("x11","low_label_font_bug")

  res                      = True

  res@cnInfoLabelOn              = False          ; no contour info label

  res@cnHighLabelsOn             = True           ; high labels on
  res@cnHighLabelBackgroundColor = "white"        ; background white
  res@cnHighLabelPerimOn         = True           ; box on
  res@cnHighLabelFontColor       = "Red"

  res@cnLowLabelsOn              = True            ; low label on
  res@cnLowLabelBackgroundColor  = "white"         ; background white
  res@cnLowLabelPerimOn          = True            ; box on
  res@cnLowLabelFontColor        = "Blue"

  res@cnLowLabelFontHeightF      = 0.02

  res@gsnMaximize                = True
  res@gsnRightString             = ""
  res@gsnLeftString              = ""

  res@tiMainString = "cnLowLabelFontHeightF has no effect"
  plot = gsn_csm_contour(wks,chi(0,:,:),res)

  res@cnHighLabelFontHeightF     = 0.02   ; this affects low labels as well
  res@tiMainString               = "low labels affected by cnHighLabelFontHeightF"
  plot = gsn_csm_contour(wks,chi(0,:,:),res)

  res@cnLowLabelAngleF           = -90.
  res@tiMainString               = "cnLowLabelAngleF has no effect"
  plot = gsn_csm_contour(wks,chi(0,:,:),res)

  res@cnHighLabelAngleF          = 90.
  res@tiMainString               = "low labels rotated by cnHighLabelAngleF"
  plot = gsn_csm_contour(wks,chi(0,:,:),res)

end