load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
 f     = addfile ("atmos.nc","r")
 u     = f->U

 wks   = gsn_open_wks ("x11","xy")                  ; send graphics to PNG file

  res                  = True
  res@gsnDraw          = False
  res@gsnFrame         = False
  res@xyLineColor      = "Blue"
  res@xyLineThicknessF = 3.0
  res@trYReverse       = True
  res@tiXAxisString    = ""
  res@tiYAxisString    = ""

;---Create three XY plots
  plots = new(3,graphic)
  plots(0) = gsn_csm_xy (wks,u(0,:,{10},{0}),u&lev,res)
  plots(1) = gsn_csm_xy (wks,u(0,:,{20},{0}),u&lev,res)
  plots(2) = gsn_csm_xy (wks,u(0,:,{30},{0}),u&lev,res)

;---Panel the three plots, note the figure string covers the line in the third plot
  pres                        = True
  pres@gsnMaximize            = True
  pres@gsnPanelFigureStringsJust = "BottomLeft"
  pres@gsnPanelFigureStrings     = (/"a","b","c"/) + ")"
  pres@gsnPanelMainString        = "Figure string 'c)' overlaps plot"
  gsn_panel(wks,plots,(/2,2/),pres)	

;Solution 1: Set the background color of the strings to transparent
  pres@gsnPanelFigureStringsBackgroundFillColor = "transparent"
  pres@gsnPanelMainString                       = "Set figure strings to have transparent background"
  gsn_panel(wks,plots,(/2,2/),pres)	
  
;Solution 2: Create the third plot with an extra margin to allow room for the labela
  pres@gsnPanelFigureStringsBackgroundFillColor = "yellow"
  res@trXMinF          = -15    ; add an extra margin
  plots(2) = gsn_csm_xy (wks,u(0,:,{30},{0}),u&lev,res)
  pres@gsnPanelMainString  = "Set minimum X axis to -20 on third plot"
  gsn_panel(wks,plots,(/2,2/),pres)	


end