;   Example script - plot terrain (using some basic WRF scripts)
;   Map info is now added via the special "wrf_map_overlays" function
;   November 2008

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"  ; Add special wrf functions
load "./wrf_add_wps_dom.ncl"

begin

  a = addfile("./geo_em.d01.nc","r")   ; Open a file


;  type = "x11"
; type = "pdf"
; type = "ps"
 type = "png"
  wks = gsn_open_wks(type,"plt_geo_4")       ; Create a plot workstation


  opts = True                                ; Set some Basic Plot options
  opts@MainTitle = "GEOGRID FIELDS"

  ter = a->HGT_M(0,:,:)                      ; Read the variable to memory

  res = opts                                 ; Use basic options for this field
  res@cnFillOn = True                        ; Create a color fill plot

  contour = wrf_contour(a,wks,ter,res)

  pltres = True                              ; Set plot options
  mpres = True                               ; Set map options
  pltres@PanelPlot = True                    ; Don't remove contour plot after the overlay
  plot = wrf_map_overlays(a,wks,(/contour/),pltres,mpres)  ; Plot the data over a map background

  plot = wrf_add_wps_dom(wks,plot)    ;  Add domain boxes to map

  draw(plot)     ; This will draw contours, map, domain lines, and text
  frame(wks)
end