;----------------------------------------------------------------------
; This script creates plots from "wind.ascii" and "temp.ascii",
; downloaded from:
;
; http://www.sparc-climate.org/data-center/data-access/reference-climatologies/randels-climatologies/temperature-wind-climatology/
;
; The data and README file can be found at:
;    ftp://sparc-ftp1.ceda.ac.uk/sparc/ref_clim/randel/temp_wind/
;----------------------------------------------------------------------
; This script creates very basic contour plots.  See
; plot_sparc_data_custom.ncl for more complicated, customized plots.
;----------------------------------------------------------------------
begin
  temp_filename = "temp.ascii"
  wind_filename = "wind.ascii"

  temp = asciiread(temp_filename,(/33,41,12/),"float")
  wind = asciiread(wind_filename,(/46,41,12/),"float")

  wind@_FillValue = 1e36    ; missing value, IMPORTANT!

;---Make sure data looks good
  printVarSummary(temp)
  printMinMax(temp,0)

  printVarSummary(wind)
  printMinMax(wind,0)

;---Start the graphics
  wks = gsn_open_wks("x11","sparc_basic")

  res                      = True
  res@cnFillOn             = True     ; turn on contour fill
  res@cnLineLabelsOn       = False    ; turn off line labels
  res@lbOrientation        = "Vertical"

;---Loop through time and create a series of plots
  MMM = month_name(0)    ; Jan, Feb, ..
  do nt=0,11
    res@tiMainString = temp_filename + " - " + MMM(nt)
    plot_temp = gsn_csm_contour(wks,temp(:,:,nt),res)
  end do

  do nt=0,11
    res@tiMainString = wind_filename + " - " + MMM(nt)
    plot_wind = gsn_csm_contour(wks,wind(:,:,nt),res)
  end do

end