;================================================;
;  maponly_1.ncl
;================================================;
;
; Concepts illustrated:
;   - Compares different map resolutions for a world map
;
;================================================;
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"   
; ================================================;
begin

  wks  = gsn_open_wks("png","mapcompare")

  res              = True


  res@gsnMaximize  = True
  res@tiMainString = "NCL's default map outlines"
  res@mpFillOn     = False

  plot = gsn_csm_map_ce(wks,res)


  res@tiMainString      = "NCL's medium resolution map outlines"
  res@mpDataBaseVersion = "MediumRes"

  plot = gsn_csm_map_ce(wks,res)

;
; GSHHS shapefiles downloaded from
;
;    http://www.ngdc.noaa.gov/mgg/shorelines/data/gshhg/latest/
;
; There are several *.shp files, so look at the README file 
; to decide which one you want
;
  dir      = "GSHHS_SHP/"
  filename = "l/GSHHS_l_L1.shp"

  res@mpOutlineOn       = False
  res@gsnDraw           = False
  res@gsnFrame          = False
  res@tiMainString      = dir+filename
  plot = gsn_csm_map_ce(wks,res)


  dum = gsn_add_shapefile_polylines(wks,plot,dir+filename,True)
  draw(plot)
  frame(wks)
end