;***********************************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
;************************************************************************
begin

;   dir      = "/work/users/nof/data/data_new/Ozone/grid1/seasons/Europe/"
    dir      = "./"
    filename = "mda8.surfO3.EU.2000.2009.settabs_JJA.nc"
    ozfil = addfile(dir + filename,"r")

    wks = gsn_open_wks("png","mda")

    ;ozone
    oz           = ozfil->MDA8_SurfO3

    ; replace the NaNs with missing values
    oz@_FillValue = default_fillvalue(typeof(oz)) 
    replace_ieeenan(oz,oz@_FillValue,0)

    ; reorder
    oz_reord     = oz(time|:,lat|:,lon|:)

    ; fix the longitudes
    oz_reord&lon = where((oz_reord&lon.gt.180).and.(oz_reord&lon.lt.360),\
                          oz_reord&lon-360,oz_reord&lon)
 
    res                       = True
    res@gsnMaximize           = True

    res@cnFillOn              = True
    res@cnLinesOn             = False
    res@cnFillPalette         = "BlueDarkRed18"

    res@gsnAddCyclic          = False

    res@mpDataBaseVersion     = "MediumRes"        ; better map outlines
    res@mpMinLonF             = min(oz_reord&lon)
    res@mpMinLatF             = min(oz_reord&lat)
    res@mpMaxLonF             = max(oz_reord&lon)
    res@mpMaxLatF             = max(oz_reord&lat)

    res@pmTickMarkDisplayMode = "Always"           ; nicer tickmarks

    res@gsnLeftString         = "surface ozone"    ; default titles
    res@gsnRightString        = "ppb"              ; are too long

    plot = gsn_csm_contour_map(wks,oz_reord(0,:,:),res)

end
;******************************************