;;diri = "/home/gopi/Build_WRF/work/MODE_analyis/Nirmala/"
  diri = "./"
  fili = (/"GPM_jun_2016"  , "GPM_july_2016"  \
          ,"GPM_aug_2016"  , "GPM_sept_2016"  /)
  nfil = dimsizes(fili)

  do nf=0,nfil-1
     a  = addfile(diri+fili(nf)+".nc","r")
     if (nf.eq.0) then
         APCP = a->rain           ; 1st month: rain(lat, lon)
     else
         APCP = APCP + (a->rain)  ; add other months
     end if
  end do
  APCP@long_name = "June-Sept: Total Rain"
;;APCP@units     = "???"

  APCP = APCP/nfil                ; average
  APCP@long_name = "June-Sept: Mean Monthly RainFall"
  printVarSummary(APCP)
  printMinMax(APCP,0)
  print("-----")

;************************************************
; Examine the statistical dispersion
;************************************************
  opt = True
  opt@PrintStat = True
  statAPCP = stat_dispersion(APCP, opt )

;************************************************
; create plot
;************************************************
  wks = gsn_open_wks("png" ,"Govind_2016")      ; send graphics to PNG file

  res                      = True     ; plot mods desired

  res@gsnMaximize          = True     ; Make plot fit the frame
  res@gsnAddCyclic         = False    ; data already has cyclic point
  res@cnFillOn             = True     ; turn on color fill
  res@cnLinesOn            = False    ; turn off contour lines
  res@cnLineLabelsOn       = False    ; turn off contour line labels
  res@cnFillPalette        = "BlAqGrYeOrRe"
  res@lbOrientation        = "Vertical"
  res@cnFillMode           = "RasterFill"       ; Raster Mode

  res@cnLevelSelectionMode = "ManualLevels"     ; set manual contour levels
  res@cnMinLevelValF       =  50.               ; set min contour level
  res@cnMaxLevelValF       = 350.               ; set max contour level
  res@cnLevelSpacingF      =  25.               ; set contour spacing

  res@mpMinLatF            = min(APCP&lat)
  res@mpMaxLatF            = max(APCP&lat)
  res@mpMinLonF            = min(APCP&lon)
  res@mpMaxLonF            = max(APCP&lon)
  res@mpOutlineDrawOrder   = "PostDraw"      ; draw continental outline last
  res@mpOutlineSpecifiers  = (/"India","Nepal"/) 
  res@pmTickMarkDisplayMode= "Always"        ; use NCL default lat/lon labels

;;res@tiMainString = "Mean Monthly Rainfall""
  plot = gsn_csm_contour_map(wks,APCP, res)