[Dart-dev] [6873] DART/trunk/models/CESM/shell_scripts/CESM1_2_1_setup_hybrid: First crack at running CESM 1_2_1.
nancy at ucar.edu
nancy at ucar.edu
Fri Apr 4 15:53:47 MDT 2014
Revision: 6873
Author: thoar
Date: 2014-04-04 15:53:47 -0600 (Fri, 04 Apr 2014)
Log Message:
-----------
First crack at running CESM 1_2_1. The WAV model is new.
The SourceMods from 1_1_1 have been ported to 1_2_1 but have yet to
be extensively tested. Supports CLM 4 and 4.5.
The rtm.buildnml.csh script is (in my opinion) broken in the 1_2_1 distribution
and my replacement is in the DART file file.
Automatically detects the CAM dycore and the CLM physics and links
the right sourcemods.
Added Paths:
-----------
DART/trunk/models/CESM/shell_scripts/CESM1_2_1_setup_hybrid
-------------- next part --------------
Added: DART/trunk/models/CESM/shell_scripts/CESM1_2_1_setup_hybrid
===================================================================
--- DART/trunk/models/CESM/shell_scripts/CESM1_2_1_setup_hybrid (rev 0)
+++ DART/trunk/models/CESM/shell_scripts/CESM1_2_1_setup_hybrid 2014-04-04 21:53:47 UTC (rev 6873)
@@ -0,0 +1,1015 @@
+#!/bin/csh -f
+#
+# DART software - Copyright 2004 - 2013 UCAR. This open source software is
+# provided by UCAR, "as is", without charge, subject to all terms of use at
+# http://www.image.ucar.edu/DAReS/DART/DART_download
+#
+# DART $Id$
+
+# ==============================================================================
+#
+# ---------------------
+# Purpose
+# ---------------------
+#
+# This script is designed to set up, stage, and build a multi-instance run of CESM
+# using a B compset where CAM, POP, and CLM are all active. The initial states
+# come from a single multi-instance reference case so a CESM hybrid setup is used.
+# While not required for CESM, POP is configured to write out netCDF restart files
+# because they are required by DART (if you are going to assimilate ocean obs).
+#
+# Because the atmosphere assimilations typically occur every 6 hours, the methodology
+# here reflects that. All of CESM stops every 6 hours (requiring the ocean to couple
+# 4x per day) so that a CAM output file would be available for assimilation.
+#
+# CESM/DART requires some modifications to the CESM source code EVEN IF YOU
+# ARE NOT USING DART. The modifications for CAM require a change to the CESM
+# ${CASE}.run script to invoke a DART script that will allow CAM to cycle
+# correctly with the source code modifications. Changing one line will
+# allow you to invoke DART.
+#
+# This script results in a viable setup for a CESM multi-instance experiment.
+# You are STRONGLY encouraged to run the multi-instance CESM a few times and
+# experiment with different settings BEFORE you try to assimilate observations.
+# The data volume is quite large and you should become comfortable using
+# CESM's restart capability to re-stage files in your RUN directory.
+#
+# ${CASEROOT}/CESM_DART_config is automatically run by this script and will
+# augment the CESM case with the required setup and configuration to use DART
+# to perform an assimilation. CESM_DART_config will insert a few dozen
+# lines into the ${case}.run script after it makes a backup copy.
+#
+# This script relies heavily on the information in:
+# http://www.cesm.ucar.edu/models/cesm1.2/cesm/doc/usersguide/book1.html
+#
+# ---------------------
+# How to use this script.
+# ---------------------
+#
+# -- You will have to read and understand the script in its entirety.
+# You will have to modify things outside this script.
+# This script sets up a plain CESM multi-instance run without DART,
+# intentionally. Once it is running, calls to DART can be added.
+#
+# -- Examine the whole script to identify things to change for your experiments.
+#
+# -- Edit this script in the $DART/models/CESM/shell_scripts directory
+# or copy it to somewhere where it will be preserved.
+#
+# -- Locate the initial multi-instance files that CESM will need.
+#
+# -- Run this script. When it is executed, it will create:
+# 1) a CESM 'CASE' directory, where the model will be built,
+# 2) a run directory, where each forecast (and assimilation) will take place,
+# 3) a bld directory for the executables.
+# 4) The short term archiver will use a fourth directory for
+# storage of model output until it can be moved to long term storage (HPSS)
+#
+# This script also executes ${CASEROOT}/CESM_DART_config to modify
+# the ${CASEROOT}/${CASE}.run script so that the SourceMods for CAM
+# are effective. CESM_DART_config will also augment the case with all
+# the pieces necessary to run DART when the time comes.
+#
+# -- (if running DART) Edit the DART input.nml that appears in the ${CASEROOT}
+# directory.
+#
+# -- Submit the job using ${CASEROOT}/${CASE}.submit
+#
+# ---------------------
+# Important features
+# ---------------------
+#
+# If you want to change something in your case other than the runtime
+# settings, it is safest to delete everything and start the run from scratch.
+# For the brave, read
+#
+# http://www.cesm.ucar.edu/models/cesm1.1/cesm/doc/usersguide/x1142.html
+#
+# and you may be able to salvage something with
+# ./cesm_setup -clean
+# ./cesm_setup
+# ./${case}.clean_build
+# ./${case}.build
+#
+# ==============================================================================
+
+
+
+# ==============================================================================
+# case options:
+#
+# case The value of "case" will be used many ways; directory and file
+# names both locally and on HPSS, and script names; so consider
+# its length and information content.
+# compset Must be one of the CESM standard names, see the CESM documentation
+# for supported strings.
+# resolution Sets the model grid resolution, see the CESM documentation.
+# cesmtag The version of the CESM source code to use when building the code.
+# num_instances The number of ensemble members.
+# ==============================================================================
+# 2000_CAM5_CLM40%CN_CICE_POP2_RTM_SGLC_SWAV (B_2000_CAM5_CN) (BC5CN)
+
+setenv case cesm_test2
+setenv compset 2000_CAM5_CLM40%CN_CICE_POP2_RTM_SGLC_SWAV
+setenv resolution 0.9x1.25_gx1v6
+setenv cesmtag cesm1_2_1
+setenv num_instances 30
+
+# ==============================================================================
+# machines and directories:
+#
+# mach Computer name
+# cesmroot Location of the CESM code base. This version of the script
+# only supports version cesm1_2_1.
+# caseroot Will create the CESM case directory here, where the CESM+DART
+# configuration files will be stored. This should probably not
+# be in scratch (on yellowstone, your 'work' partition is suggested).
+# This script will delete any existing caseroot, so this script,
+# and other useful things should be kept elsewhere.
+# rundir Will create the CESM run directory here. Will need large
+# amounts of disk space, generally on a scratch partition.
+# exeroot Will create the CESM executable directory here, where the
+# CESM executables will be built. Medium amount of space
+# needed, generally on a scratch partition.
+# archdir Will create the CESM short-term archive directories here.
+# Large, generally on a scratch partition. Files will remain
+# here until the long-term archiver moves it to permanent storage.
+# dartroot Location of the root of _your_ DART installation
+# ==============================================================================
+
+setenv mach yellowstone
+setenv cesmdata /glade/p/cesm/cseg/inputdata
+setenv cesmroot /glade/p/cesm/cseg/collections/$cesmtag
+setenv caseroot /glade/p/work/${USER}/cases/${case}
+setenv rundir /glade/scratch/${USER}/${case}/run
+setenv exeroot /glade/scratch/${USER}/${case}/bld
+setenv archdir /glade/scratch/${USER}/archive/${case}
+setenv dartroot /glade/u/home/${USER}/svn/DART/trunk
+
+# ==============================================================================
+# configure settings:
+#
+# refcase The name of the existing reference case that this run will
+# start from.
+#
+# refyear The specific date/time-of-day in the reference case that this
+# refmon run will start from. (Also see 'runtime settings' below for
+# refday start_year, start_mon, start_day and start_tod.)
+# reftod
+#
+# stagedir The directory location of the reference case files.
+# ==============================================================================
+
+setenv refcase cesm_hybrid
+setenv refyear 2004
+setenv refmon 01
+setenv refday 10
+setenv reftod 00000
+
+# useful combinations of time that we use below
+setenv refdate $refyear-$refmon-$refday
+setenv reftimestamp $refyear-$refmon-$refday-$reftod
+
+setenv stagedir /glade/p/image/CESM_initial_ensemble/rest/${reftimestamp}
+
+# ==============================================================================
+# runtime settings:
+#
+# start_year generally this is the same as the reference case date, but it can
+# start_month be different if you want to start this run as if it was a different time.
+# start_day
+# start_tod
+#
+# short_term_archiver Copies the files from each job step to a 'rest' directory.
+# long_term_archiver Puts the files from all completed steps on tape storage.
+#
+# resubmit How many job steps to run on continue runs (should be 0 initially)
+# stop_option Units for determining the forecast length between assimilations
+# first_stop_n Number of time units in the first forecast
+# stop_n Number of time units in all subsequent forecasts
+#
+# clm_dtime CLM dynamical timestep (in seconds) ... 1800 is the default
+# h1nsteps is the number of time steps to put in a single CLM .h1. file
+# DART needs to know this and the only time it is known is during
+# this configuration step. Changing the value later has no effect.
+#
+# If the long-term archiver is off, you get a chance to examine the files before
+# they get moved to long-term storage. You can always submit $CASE.l_archive
+# whenever you want to free up space in the short-term archive directory.
+# ==============================================================================
+
+setenv start_year 2004
+setenv start_month 01
+setenv start_day 10
+setenv start_tod 00000
+
+setenv short_term_archiver on
+setenv long_term_archiver off
+
+setenv resubmit 0
+setenv stop_option nhours
+setenv first_stop_n 12
+setenv stop_n 6
+
+@ clm_dtime = 1800
+@ h1nsteps = $stop_n * 3600 / $clm_dtime
+
+# ==============================================================================
+# job settings:
+#
+# queue can be changed during a series by changing the ${case}.run
+# timewall can be changed during a series by changing the ${case}.run
+#
+# TJH: Advancing 30 instances for 12 hours with 900 pes (30*15*2) with
+# an assimilation step took about 17 minutes on yellowstone.
+# ==============================================================================
+
+setenv ACCOUNT P8685xxxx
+setenv queue economy
+setenv timewall 0:30
+
+# ==============================================================================
+# standard commands:
+#
+# If you are running on a machine where the standard commands are not in the
+# expected location, add a case for them below.
+# ==============================================================================
+
+set nonomatch # suppress "rm" warnings if wildcard does not match anything
+
+# The FORCE options are not optional.
+# The VERBOSE options are useful for debugging though
+# some systems don't like the -v option to any of the following
+switch ("`hostname`")
+ case be*:
+ # NCAR "bluefire"
+ set MOVE = '/usr/local/bin/mv -fv'
+ set COPY = '/usr/local/bin/cp -fv --preserve=timestamps'
+ set LINK = '/usr/local/bin/ln -fvs'
+ set REMOVE = '/usr/local/bin/rm -fr'
+
+ breaksw
+ default:
+ # NERSC "hopper", NWSC "yellowstone"
+ set MOVE = '/bin/mv -fv'
+ set COPY = '/bin/cp -fv --preserve=timestamps'
+ set LINK = '/bin/ln -fvs'
+ set REMOVE = '/bin/rm -fr'
+
+ breaksw
+endsw
+
+# ==============================================================================
+# ==============================================================================
+# by setting the values above you should be able to execute this script and
+# have it run. however, for running a real experiment there are still many
+# settings below this point - e.g. component namelists, history file options,
+# the processor layout, xml file options, etc - that you will almost certainly
+# want to change before doing a real science run.
+# ==============================================================================
+# ==============================================================================
+
+
+# ==============================================================================
+# Make sure the CESM directories exist.
+# VAR is the shell variable name, DIR is the value
+# ==============================================================================
+
+foreach VAR ( cesmroot dartroot stagedir )
+ set DIR = `eval echo \${$VAR}`
+ if ( ! -d $DIR ) then
+ echo "ERROR: directory '$DIR' not found"
+ echo " In the setup script check the setting of: $VAR "
+ exit -1
+ endif
+end
+
+# ==============================================================================
+# Create the case - this creates the CASEROOT directory.
+#
+# For list of the pre-defined component sets: ./create_newcase -list
+# To create a variant compset, see the CESM documentation and carefully
+# incorporate any needed changes into this script.
+# ==============================================================================
+
+# fatal idea to make caseroot the same dir as where this setup script is
+# since the build process removes all files in the caseroot dir before
+# populating it. try to prevent shooting yourself in the foot.
+
+if ( $caseroot == `dirname $0` ) then
+ echo "ERROR: the setup script should not be located in the caseroot"
+ echo "directory, because all files in the caseroot dir will be removed"
+ echo "before creating the new case. move the script to a safer place."
+ exit -1
+endif
+
+echo "removing old files from ${caseroot}"
+echo "removing old files from ${exeroot}"
+echo "removing old files from ${rundir}"
+${REMOVE} ${caseroot}
+${REMOVE} ${exeroot}
+${REMOVE} ${rundir}
+
+${cesmroot}/scripts/create_newcase -case ${caseroot} -mach ${mach} \
+ -res ${resolution} -compset ${compset}
+
+if ( $status != 0 ) then
+ echo "ERROR: Case could not be created."
+ exit -1
+endif
+
+# preserve a copy of this script as it was run
+set ThisFileName = $0:t
+${COPY} $ThisFileName ${caseroot}/${ThisFileName}.original
+
+# ==============================================================================
+# Record the DARTROOT directory and copy the DART setup script to CASEROOT.
+# CESM_DART_config can be run at some later date if desired, but it presumes
+# to be run from a CASEROOT directory. If CESM_DART_config does not exist locally,
+# then it better exist in the expected part of the DARTROOT tree.
+# ==============================================================================
+
+if ( ! -e CESM_DART_config ) then
+ ${COPY} ${dartroot}/models/CESM/shell_scripts/CESM_DART_config .
+endif
+
+if ( -e CESM_DART_config ) then
+ sed -e "s#BOGUS_DART_ROOT_STRING#$dartroot#" \
+ -e "s#HISTORY_OUTPUT_INTERVAL#$stop_n#" < CESM_DART_config >! temp.$$
+ ${MOVE} temp.$$ ${caseroot}/CESM_DART_config
+ chmod 755 ${caseroot}/CESM_DART_config
+else
+ echo "ERROR: the script to configure for data assimilation is not available."
+ echo " CESM_DART_config MUST be present locally or in"
+ echo " ${dartroot}/models/CESM/shell_scripts/"
+ exit -2
+endif
+
+# ==============================================================================
+# Configure the case.
+# ==============================================================================
+
+cd ${caseroot}
+
+source ./Tools/ccsm_getenv || exit -2
+
+# MAX_TASKS_PER_NODE comes from $case/Tools/mkbatch.$machine
+@ ptile = $MAX_TASKS_PER_NODE / 2
+@ nthreads = 1
+
+# Save a copy for debug purposes
+foreach FILE ( *xml )
+ if ( ! -e ${FILE}.original ) then
+ ${COPY} $FILE ${FILE}.original
+ endif
+end
+
+if ($num_instances <= 4) then
+
+ # This is only for the purpose of debugging the code.
+ @ atm_tasks = $ptile * $num_instances * 4
+ @ lnd_tasks = $ptile * $num_instances * 4
+ @ ice_tasks = $ptile * $num_instances * 4
+ @ ocn_tasks = $ptile * $num_instances * 4
+ @ cpl_tasks = $ptile * $num_instances
+ @ glc_tasks = $ptile * $num_instances
+ @ rof_tasks = $ptile * $num_instances * 4
+ @ wav_tasks = $ptile * $num_instances
+
+else
+
+ # This works, but a more efficient layout should be used
+ @ atm_tasks = $ptile * $num_instances * 2
+ @ lnd_tasks = $ptile * $num_instances * 2
+ @ ice_tasks = $ptile * $num_instances * 2
+ @ ocn_tasks = $ptile * $num_instances * 2
+ @ cpl_tasks = $ptile * $num_instances
+ @ glc_tasks = $ptile * $num_instances
+ @ rof_tasks = $ptile * $num_instances * 2
+ @ wav_tasks = $ptile * $num_instances
+
+endif
+
+# echo "task partitioning ... perhaps ... atm // ocn // lnd+ice+glc+rof"
+# presently, all components run 'serially' - one after another.
+echo ""
+echo "ATM gets $atm_tasks"
+echo "LND gets $lnd_tasks"
+echo "ICE gets $ice_tasks"
+echo "OCN gets $ocn_tasks"
+echo "CPL gets $cpl_tasks"
+echo "GLC gets $glc_tasks"
+echo "ROF gets $rof_tasks"
+echo "WAV gets $wav_tasks"
+echo ""
+
+./xmlchange NTHRDS_ATM=$nthreads,NTASKS_ATM=$atm_tasks,NINST_ATM=$num_instances
+./xmlchange NTHRDS_LND=$nthreads,NTASKS_LND=$lnd_tasks,NINST_LND=$num_instances
+./xmlchange NTHRDS_ICE=$nthreads,NTASKS_ICE=$ice_tasks,NINST_ICE=$num_instances
+./xmlchange NTHRDS_OCN=$nthreads,NTASKS_OCN=$ocn_tasks,NINST_OCN=$num_instances
+./xmlchange NTHRDS_CPL=$nthreads,NTASKS_CPL=$cpl_tasks
+./xmlchange NTHRDS_GLC=$nthreads,NTASKS_GLC=$glc_tasks,NINST_GLC=1
+./xmlchange NTHRDS_ROF=$nthreads,NTASKS_ROF=$rof_tasks,NINST_ROF=$num_instances
+./xmlchange NTHRDS_WAV=$nthreads,NTASKS_WAV=$wav_tasks,NINST_WAV=1
+./xmlchange ROOTPE_ATM=0
+./xmlchange ROOTPE_LND=0
+./xmlchange ROOTPE_ICE=0
+./xmlchange ROOTPE_OCN=0
+./xmlchange ROOTPE_CPL=0
+./xmlchange ROOTPE_GLC=0
+./xmlchange ROOTPE_ROF=0
+./xmlchange ROOTPE_WAV=0
+
+# http://www.cesm.ucar.edu/models/cesm1.1/cesm/doc/usersguide/c1158.html#run_start_stop
+# "A hybrid run indicates that CESM is initialized more like a startup, but uses
+# initialization datasets from a previous case. This is somewhat analogous to a
+# branch run with relaxed restart constraints. A hybrid run allows users to bring
+# together combinations of initial/restart files from a previous case (specified
+# by $RUN_REFCASE) at a given model output date (specified by $RUN_REFDATE).
+# Unlike a branch run, the starting date of a hybrid run (specified by $RUN_STARTDATE)
+# can be modified relative to the reference case. In a hybrid run, the model does not
+# continue in a bit-for-bit fashion with respect to the reference case. The resulting
+# climate, however, should be continuous provided that no model source code or
+# namelists are changed in the hybrid run. In a hybrid initialization, the ocean
+# model does not start until the second ocean coupling (normally the second day),
+# and the coupler does a "cold start" without a restart file."
+#
+# TJH:
+# DART's CAM implementation causes a bit more complexity. DART only uses CAM _initial_
+# files, not RESTART files, so there are sourcemods to force a hybrid start for CAM to
+# read initial files - even when CONTINUE_RUN = TRUE. A hybrid start is better for POP
+# because the velocities are used rather than just T,S. A hybrid start is also more
+# desirable because initial values can be specified for ROF - as opposed to just zeros.
+#
+# The RUN_REFCASE/REFDATE/REFTOD are used by CLM & RTM to specify the namelist input
+# filenames - BUT - their buildnml scripts do not use the INSTANCE, so they all specify
+# the same (single) filename. This is remedied by using patched [clm,rtm].buildnml.csh
+# scripts that exist in the SourceMods directory.
+
+./xmlchange RUN_TYPE=hybrid
+./xmlchange RUN_STARTDATE=${start_year}-${start_month}-${start_day}
+./xmlchange START_TOD=$start_tod
+./xmlchange RUN_REFCASE=$refcase
+./xmlchange RUN_REFDATE=$refdate
+./xmlchange RUN_REFTOD=$reftod
+./xmlchange BRNCH_RETAIN_CASENAME=FALSE
+./xmlchange GET_REFCASE=FALSE
+./xmlchange EXEROOT=${exeroot}
+./xmlchange RUNDIR=${rundir}
+
+./xmlchange CALENDAR=GREGORIAN
+
+./xmlchange STOP_OPTION=$stop_option
+./xmlchange STOP_N=$first_stop_n
+./xmlchange CONTINUE_RUN=FALSE
+./xmlchange RESUBMIT=$resubmit
+
+./xmlchange PIO_TYPENAME=pnetcdf
+./xmlchange MPI_RUN_COMMAND=mpirun.lsf
+
+# COUPLING discussion.
+# http://bugs.cgd.ucar.edu/show_bug.cgi?id=1740
+# "In summary, users should ensure that the following is true,
+# ATM_NCPL = LND_NCPL = ICE_NCPL >= ROF_NCPL >= OCN_NCPL"
+#
+# OCN_NCPL == 4 sets the ocean coupling time to 6 hours.
+# All related namelist settings are based on this value.
+# OCN_NCPL is # coupling intervals per NCPL_BASE_PERIOD (default 'day')
+# Since OCN_NCPL and GLC_NCPL default to the same value, I am
+# keeping them the same.
+
+./xmlchange ROF_NCPL=8
+./xmlchange GLC_NCPL=4
+./xmlchange OCN_NCPL=4
+
+# The river transport model ON is useful only when using an active ocean or
+# land surface diagnostics. Setting ROF_GRID to 'null' turns off the RTM.
+
+#./xmlchange ROF_GRID='null'
+#./xmlchange RTM_MODE="NULL"
+
+./xmlchange DOUT_S_ROOT=${archdir}
+./xmlchange DOUT_S_SAVE_INT_REST_FILES=FALSE
+./xmlchange DOUT_L_MSROOT="csm/${case}"
+./xmlchange DOUT_L_HTAR=FALSE
+
+if ($short_term_archiver == 'off') then
+ ./xmlchange DOUT_S=FALSE
+else
+ ./xmlchange DOUT_S=TRUE
+endif
+if ($long_term_archiver == 'off') then
+ ./xmlchange DOUT_L_MS=FALSE
+else
+ ./xmlchange DOUT_L_MS=TRUE
+endif
+
+# level of debug output, 0=minimum, 1=normal, 2=more, 3=too much, valid values: 0,1,2,3 (integer)
+
+./xmlchange DEBUG=FALSE
+./xmlchange INFO_DBUG=0
+
+# ==============================================================================
+# Update source files.
+# Ideally, using DART would not require any modifications to the model source.
+# Until then, this script accesses sourcemods from a hardwired location.
+# If you have additional sourcemods, they will need to be merged into any DART
+# mods and put in the SourceMods subdirectory found in the 'caseroot' directory.
+# ==============================================================================
+
+if ( -d ~/${cesmtag}/SourceMods ) then
+
+ # Copy all of the 'generic' SourceMods
+
+ ${COPY} -r ~/${cesmtag}/SourceMods/* ${caseroot}/SourceMods/
+
+ # Each CLM version has some SourceMods. Link to the right version.
+ # must parse from a variable of the form:
+ # CLM_CONFIG_OPTS: -phys clm4_0 -bgc cn
+ # FIXME ... if bgc off ... can I still copy in CNBalanceCheckMod.F90
+
+ set clm_opts = `echo $CLM_CONFIG_OPTS | sed -e "s/-//"`
+
+ @ iarg = 1
+ while ($iarg <= $#clm_opts)
+
+ @ iargp1 = $iarg + 1
+ set option = $clm_opts[$iarg]
+ set value = $clm_opts[$iargp1]
+
+ switch ( ${option} )
+ case "phys":
+ if ( -e SourceMods/src.clm/src/${value} ) then
+ cd SourceMods/src.clm
+ ${LINK} src/${value}/*/*F90 .
+ cd ../..
+ else
+ echo "No SourceMods for CLM <${value}>."
+ echo "Got the version from CLM_CONFIG_OPTS ... <${CLM_CONFIG_OPTS}>"
+ endif
+ breaksw
+ # case "bgc": FIXME ... any special action needed here?
+ # breaksw
+
+ default:
+ breaksw
+ endsw
+
+ @ iarg = $iarg + 2
+ end
+
+ # Each CAM dynamical core has its own SourceMods
+
+ if ( -e SourceMods/src.cam/src/dynamics/${CAM_DYCORE} ) then
+ cd SourceMods/src.cam
+ ${LINK} src/dynamics/${CAM_DYCORE}/*F90 .
+ cd ../..
+ else
+ echo "No SourceMods for CAM dycore <${CAM_DYCORE}>."
+ endif
+
+else
+ echo "ERROR - No SourceMods for this case."
+ echo "ERROR - No SourceMods for this case."
+ echo "DART requires modifications to several src files."
+ echo "These files can be downloaded from:"
+ echo "http://www.image.ucar.edu/pub/DART/CESM/DART_SourceMods_cesm1_2_1_18Mar2014.tar"
+ echo "untar these into your HOME directory - they will create a"
+ echo "~/cesm_1_2_1 directory with the appropriate SourceMods structure."
+ exit -4
+endif
+
+# The CESM multi-instance capability is relatively new and still has a few
+# implementation bugs. These are known problems and will be fixed soon.
+# this should be removed when the files are fixed:
+
+echo "REPLACING BROKEN CESM FILES HERE - SHOULD BE REMOVED WHEN FIXED"
+echo caseroot is ${caseroot}
+if ( -d ~/${cesmtag} ) then
+
+ # preserve the original version of the files
+ if ( ! -e ${caseroot}/Buildconf/rtm.buildnml.csh.original ) then
+ ${COPY} ${caseroot}/Buildconf/rtm.buildnml.csh \
+ ${caseroot}/Buildconf/rtm.buildnml.csh.original
+ endif
+
+ # patch/replace the broken files (first used by cesm_setup)
+ ${COPY} ~/${cesmtag}/rtm.buildnml.csh ${caseroot}/Buildconf/.
+
+endif
+
+# ==============================================================================
+# Set up the case.
+# This creates the EXEROOT and RUNDIR directories.
+# ==============================================================================
+
+echo 'Setting up the case ...'
+
+./cesm_setup
+
+if ( $status != 0 ) then
+ echo "ERROR: Case could not be set up."
+ exit -2
+endif
+
+# ==============================================================================
+# Edit the run script to reflect queue and wallclock
+# ==============================================================================
+
+echo ''
+echo 'Updating the run script to set wallclock and queue.'
+echo ''
+
+if ( ! -e ${case}.run.original ) then
+ ${COPY} ${case}.run ${case}.run.original
+endif
+
+source Tools/ccsm_getenv
+set BATCH = `echo $BATCHSUBMIT | sed 's/ .*$//'`
+switch ( $BATCH )
+ case bsub*:
+ # NCAR "bluefire", "yellowstone"
+ set TIMEWALL=`grep BSUB ${case}.run | grep -e '-W' `
+ set QUEUE=`grep BSUB ${case}.run | grep -e '-q' `
+ sed -e "/BSUB/s#$TIMEWALL[3]#$timewall#" \
+ -e "/BSUB/s#ptile=[0-9][0-9]*#ptile=$ptile#" \
+ -e "/BSUB/s#$QUEUE[3]#$queue#" < ${case}.run >! temp.$$
+ ${MOVE} temp.$$ ${case}.run
+ chmod 755 ${case}.run
+ breaksw
+
+ case msub*:
+ # juropa
+ set TIMEWALL=`grep MSUB ${case}.run | grep -e '-l walltime' `
+ set WALLTIME = `echo $TIMEWALL[$#TIMEWALL] | sed 's#=# #'`
+ sed -i /MSUB/s/$WALLTIME[$#WALLTIME]/$timewall/ ${case}.run
+ breaksw
+
+ default:
+ breaksw
+endsw
+
+# This is the part that modifies the run script to allow CESM to advance
+# correctly given the modifications of CAM for DART. It also copies several
+# required DART files to the caseroot directory.
+
+./CESM_DART_config || exit -3
+
+# ==============================================================================
+# Modify namelist templates for each instance.
+#
+# In a hybrid run with CONTINUE_RUN = FALSE (i.e. just starting up):
+#
+# CAM has been forced to read initial files - specified by namelist var:ncdata
+# POP reads from pointer files
+# CICE reads from namelist variable 'ice_ic'
+# CLM builds its own 'finidat' value from the REFCASE variables.
+# RTM reads from namelist variable 'finidat_rtm', but rtm.buildnml.csh also is buggy.
+#
+# All of these must later on be staged with these same filenames.
+# OR - all these namelists can be changed to match whatever has been staged.
+# MAKE SURE THE STAGING SECTION OF THIS SCRIPT MATCHES THESE VALUES.
+# ==============================================================================
+
+@ inst = 1
+while ($inst <= $num_instances)
+
+ # following the CESM strategy for 'inst_string'
+ set inst_string = `printf _%04d $inst`
+
+ # ===========================================================================
+ set fname = "user_nl_cam${inst_string}"
+ # ===========================================================================
+ # ATM Namelist
+ # For a HOP TEST ... empty_htapes = .false.
+ # For a HOP TEST ... use a default fincl1
+ # inithist == 'ENDOFRUN' ensures that CAM writes an initial file every time it stops.
+ # fincl1,nhtfrq,mfilt all control the history file containing a REQUIRED PHIS field.
+
+ echo " inithist = 'ENDOFRUN'" >> ${fname}
+ echo " ncdata = 'cam_initial${inst_string}.nc'" >> ${fname}
+ echo " empty_htapes = .true. " >> ${fname}
+ echo " fincl1 = 'PHIS:I' " >> ${fname}
+ echo " nhtfrq = -$stop_n " >> ${fname}
+ echo " mfilt = 1 " >> ${fname}
+
+ # ===========================================================================
+ set fname = "user_nl_clm${inst_string}"
+ # ===========================================================================
+ # LAND Namelist
+ # With a RUN_TYPE=hybrid the finidat is automatically specified
+ # using the REFCASE/REFDATE/REFTOD information. i.e.
+ # finidat = ${stagedir}/${refcase}.clm2${inst_string}.r.${reftimestamp}.nc
+ #
+ # This is the time to consider how DART and CESM will interact. If you intend
+ # on assimilating flux tower observations (nominally at 30min intervals),
+ # then it is required to create a .h1. file with the instantaneous flux
+ # variables every 30 minutes. Despite being in a namelist, these values
+ # HAVE NO EFFECT once CONTINUE_RUN = TRUE so now is the time to set these.
+ # Check the value of h1nsteps considering STOP_N.
+ # See page 65 of:
+ # http://www.cesm.ucar.edu/models/cesm1.2/clm/models/lnd/clm/doc/UsersGuide/clm_ug.pdf
+ # equivalently, Example 1-4 in:
+ # http://www.cesm.ucar.edu/models/cesm1.2/clm/models/lnd/clm/doc/UsersGuide/x1867.html
+ #
+ # DART's forward observation operators for these fluxes just reads them
+ # from the .h1. file rather than trying to create them from the subset of
+ # CLM variables that are available in the DART state vector. We have a terrible
+ # time trying to predict the .h1. filename given only current model time.
+ # DART does not read the clm namelist input that has this information, and
+ # since it is in a namelist - it can change during the course of a run - BUT
+ # as discussed above, only the first settings are important. Tricky.
+ #
+ # For a HOP TEST ... hist_empty_htapes = .false.
+ # For a HOP TEST ... use a default hist_fincl1
+
+ echo "dtime = $clm_dtime" >> ${fname}
+ echo "hist_empty_htapes = .true." >> ${fname}
+ echo "hist_fincl1 = 'NEP'" >> ${fname}
+ echo "hist_fincl2 = 'NEP','FSH','EFLX_LH_TOT_R'" >> ${fname}
+ echo "hist_nhtfrq = -$stop_n,1" >> ${fname}
+ echo "hist_mfilt = 1,$h1nsteps" >> ${fname}
+ echo "hist_avgflag_pertape = 'A','A'" >> ${fname}
+
+ # ===========================================================================
+ set fname = "user_nl_pop2${inst_string}"
+ # ===========================================================================
+ # POP Namelist
+ # init_ts_suboption = 'data_assim' for non bit-for-bit restarting (assimilation mode)
+ # init_ts_suboption = 'rest' --> default behavior
+ #
+ # README:
+ # Configuring the contents of the history files for POP is best explained in
+ # the section marked "POP2: TAVG Settings" in the cesm1_2_1 pop2 namelist documentation
+ # http://www.cesm.ucar.edu/models/cesm1.2/cesm/doc/modelnl/nl_pop2.html
+ #
+ # and the CESM-specific documentation for the tavg output variables in the pop2
+ # online documentation:
+ # http://www.cesm.ucar.edu/models/cesm1.2/pop2/doc/users/node78.html
+ #
+ # In CESM1_2_1 keep the values for tavg_file_freq_opt and tavg_freq_opt identical.
+ # pop2/trunk_tags/cesm_pop_1_1_20130412 explains the issue.
+ #
+ # DEFAULT values for these are:
+ # tavg_file_freq_opt = 'nmonth' 'nmonth' 'once'
+ # tavg_freq_opt = 'nmonth' 'nday' 'once'
+ # The first entry indicates we get a monthly average once a month.
+ # The second entry indicates we get a monthly average as it is being created.
+ # The third entry indicates we get a daily timeslice
+ #
+ # Default copies of SourceMods/src.pop2/ocn.*.tavg.csh files are provided in the
+ # DART_SourceMods_cesm1_2_1.tar bundle.
+
+ echo "init_ts_suboption = 'data_assim'" >> ${fname}
+
+ # ===========================================================================
+ set fname = "user_nl_cice${inst_string}"
+ # ===========================================================================
+ # CICE Namelist
+
+ echo "ice_ic = '${refcase}.cice${inst_string}.r.${reftimestamp}.nc'" >> ${fname}
+
+ # ===========================================================================
+ set fname = "user_nl_rtm${inst_string}"
+ # ===========================================================================
+ # RIVERRUNOFF Namelist
+ # River runoff can start from an old clm restart file.
+ # you can specify the RTM filename here and override the settings from
+ # RUN_REFCASE/RUN_REFDATE/RUN_REFTOD (something you cannot do with CLM).
+
+ echo "finidat_rtm = '${cesmdata}/rof/rtm/initdata/rtmi.ICRUCLM45BGC.2000-01-01.R05_simyr2000_c130518.nc'" >> ${fname}
+
+ @ inst ++
+end
+
+./preview_namelists || exit -3
+
+# ==============================================================================
+# Stage the restarts now that the run directory exists
+# ==============================================================================
+
+set init_time = ${reftimestamp}
+
+cat << EndOfText >! stage_cesm_files
+#!/bin/csh -f
+# This script can be used to help restart an experiment from any previous step.
+# The appropriate files are copied to the RUN directory.
+#
+# Before running this script:
+# 1) be sure CONTINUE_RUN is set correctly in the env_run.xml file in
+# your CASEROOT directory.
+# CONTINUE_RUN=FALSE => you are starting over at the initial time.
+# CONTINUE_RUN=TRUE => you are starting from a previous step but not
+# the very first one.
+# 2) be sure 'restart_time' is set to the day and time that you want to
+# restart from if not the initial time.
+
+set restart_time = $init_time
+
+
+# get the settings for this case from the CESM environment
+cd ${caseroot}
+source ./Tools/ccsm_getenv || exit -2
+cd ${RUNDIR}
+
+echo 'Copying the required CESM files to the run directory to rerun'
+echo 'a previous step. CONTINUE_RUN from env_run.xml is' \$CONTINUE_RUN
+if ( \$CONTINUE_RUN == TRUE ) then
+ echo 'so files for some later step than the initial one will be restaged.'
+ echo "Date to reset files to is: \$restart_time"
+else
+ echo 'so files for the initial step of this experiment will be restaged.'
+ echo "Date to reset files to is: $init_time"
+endif
+echo ''
+
+
+if ( \$CONTINUE_RUN == TRUE ) then
+
+ #----------------------------------------------------------------------
+ # This block copies over a set of restart files from any previous step of
+ # the experiment that is NOT the initial step.
+ # After running this script resubmit the job to rerun.
+ #----------------------------------------------------------------------
+
+ echo "Staging restart files for run date/time: " \$restart_time
+
+ # The short term archiver is on, so the files we want should be in one
+ # of the short term archive 'rest' restart directories. This assumes
+ # the long term archiver has NOT copied these files to the HPSS yet.
+
+ if ( \$DOUT_S == TRUE ) then
+
+ # The restarts should be in the short term archive directory. See
+ # www.cesm.ucar.edu/models/cesm1.1/cesm/doc/usersguide/x1631.html#running_ccsm_restart_back
+ # for more help and information.
+
+ if ( ! -d \$DOUT_S_ROOT/rest/\${restart_time} ) then
+
+ echo "restart file directory not found: "
+ echo " \$DOUT_S_ROOT/rest/\${restart_time} "
+ echo "If the long-term archiver is on, you may have to restore this directory first."
+ echo "You can also check for either a .sta or a .sta2 hidden subdirectory in"
+ echo \$DOUT_S_ROOT
+ echo "which may contain the 'rest' directory you need."
+ exit -1
+
+ endif
+
+ ${COPY} \$DOUT_S_ROOT/rest/\${restart_time}/* . || exit -1
+
+ else
+
+ # The short term archiver is off, which leaves all the restart files
+ # in the run directory. The rpointer files must still be updated to
+ # point to the files with the right day/time.
+
+ @ inst=1
+ while (\$inst <= $num_instances)
+
+ set inst_string = \`printf _%04d \$inst\`
+
+ echo "${case}.clm2\${inst_string}.r.\${restart_time}.nc" >! rpointer.lnd\${inst_string}
+ echo "${case}.cice\${inst_string}.r.\${restart_time}.nc" >! rpointer.ice\${inst_string}
+ echo "${case}.cam\${inst_string}.r.\${restart_time}.nc" >! rpointer.atm\${inst_string}
+ echo "${case}.rtm\${inst_string}.r.\${restart_time}.nc" >! rpointer.rof\${inst_string}
+
+ echo "${case}.pop\${inst_string}.ro.\${restart_time}" >! rpointer.ocn\${inst_string}.ovf
+ echo "${case}.pop\${inst_string}.r.\${restart_time}.nc" >! rpointer.ocn\${inst_string}.restart
+ echo "RESTART_FMT=nc" >> rpointer.ocn\${inst_string}.restart
+
+ if ( -e rpointer.ocn\${inst_string}.tavg ) then
+ echo "${case}.pop\${inst_string}.rh.\${restart_time}.nc" >! rpointer.ocn\${inst_string}.tavg
+ endif
+ if ( -e rpointer.ocn\${inst_string}.tavg.2 ) then
+ echo "${case}.pop\${inst_string}.rh.nday1.\${restart_time}.nc" >! rpointer.ocn\${inst_string}.tavg.2
+ endif
+
+ @ inst ++
+ end
+
+ # There is only a single coupler restart file even in the multi-instance case.
+ echo "${case}.cpl.r.\${restart_time}.nc" >! rpointer.drv
+
+ endif
+
+ # Relink the CAM initial files back to the hardwired names set in the namelist
+
+ @ inst=1
+ while (\$inst <= $num_instances)
+ set inst_string = \`printf _%04d \$inst\`
+ ${LINK} ${case}.cam\${inst_string}.i.\${restart_time}.nc cam_initial\${inst_string}.nc
+ @ inst ++
+ end
+
+ echo "All files reset to rerun experiment step for time " \$restart_time
+
+else # CONTINUE_RUN == FALSE
+
+ #----------------------------------------------------------------------
+ # This block links the right files to rerun the initial (very first)
+ # step of an experiment. The names and locations are set during the
+ # building of the case; to change them rebuild the case.
+ # After running this script resubmit the job to rerun.
+ #----------------------------------------------------------------------
+
+ @ inst=1
+ while (\$inst <= $num_instances)
+
+ set inst_string = \`printf _%04d \$inst\`
+
+ echo "Staging initial files for instance \$inst of $num_instances"
+
+ ${LINK} ${stagedir}/${refcase}.clm2\${inst_string}.r.${init_time}.nc .
+ ${LINK} ${stagedir}/${refcase}.cice\${inst_string}.r.${init_time}.nc .
+ ${LINK} ${stagedir}/${refcase}.cam\${inst_string}.i.${init_time}.nc cam_initial\${inst_string}.nc
+ ${LINK} ${stagedir}/${refcase}.rtm\${inst_string}.r.${init_time}.nc .
+ ${LINK} ${stagedir}/${refcase}.pop\${inst_string}.r.${init_time}.nc .
+ ${LINK} ${stagedir}/${refcase}.pop\${inst_string}.ro.${init_time} .
+
+ echo "${refcase}.pop\${inst_string}.ro.${init_time}" >! rpointer.ocn\${inst_string}.ovf
+ echo "${refcase}.pop\${inst_string}.r.${init_time}.nc" >! rpointer.ocn\${inst_string}.restart
+ echo "RESTART_FMT=nc" >> rpointer.ocn\${inst_string}.restart
+
+ @ inst ++
+ end
+
+ echo "All files set to run the FIRST experiment step at time" $init_time
+
+endif
+exit 0
+
+EndOfText
+chmod 0755 stage_cesm_files
+
+./stage_cesm_files
+
+# ==============================================================================
+# build
+# ==============================================================================
+
+echo ''
+echo 'Building the case'
+echo ''
+
+./${case}.build
+
+if ( $status != 0 ) then
+ echo "ERROR: Case could not be built."
+ exit -5
+endif
+
+# ==============================================================================
+# What to do next
+# ==============================================================================
+
+echo ""
+echo "Time to check the case."
+echo ""
+echo "1) cd ${rundir}"
+echo " and check the compatibility between the namelists/pointer"
@@ Diff output truncated at 40000 characters. @@
More information about the Dart-dev
mailing list